Entfernen von Attributen aus der gesamten XML-Datei mit XSLT

Question

Entfernen von Attributen aus der gesamten XML-Datei mit XSLT

Gefragt el 1 de August, 2012: Wann wurde die Frage gestellt
2704 Ansichten: Anzahl der Besuche der Frage
1 Antworten: Anzahl der Fragenantworten
Gelöst: Aktueller Status der Frage

Ich muss ein bestimmtes Attribut aus der gesamten XML-Datei entfernen, während ich sie mit XSLT in eine andere XML-Datei umwandle. Ich muss das Ereignis "onclick" aus dem gesamten Dokument entfernen, wann immer es auftritt.

Eingabedatei:

<?xml version="1.0" encoding="utf-8"?>
    <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
    <html xmlns="http://www.w3.org/1999/xhtml">
    <head>
    <meta http-equiv="Content-type" content="text/html;  charset=utf-8" />
    </head>  
    <body>
      <div class="iDev">
        <div class="q">
          T <input type="radio" name="o0" id="t0" onclick="getFeedback()"/> 
        </div>
        <div class="q">
          T <input type="radio" name="o1" id="t1" onclick="getFeedback()" /> 
        </div>
      </div>
    </body>
    </html>

Mein XSLT: Ich habe versucht, dieses Attribut auf folgende Weise zu entfernen (After identity template):

<xsl:template match="xhtml:body//xhtml:input/@onclick />

In einigen Fällen wurde das "onclick"-Ereignis entfernt, aber wenn ich eine weitere Vorlage zum Ändern der Werte der Attribute "name" und "id" übergebe und ein weiteres Attribut innerhalb des Input-Tags hinzufüge, bleibt das "onclick"-Ereignis bestehen. Bitte helfen Sie mir bei der Lösung dieses Problems. Ich danke Ihnen!

Gefragt el 1 de August, 2012 von RahulD

Answer 1

1 Antworten

Answer 2

4voto

Dimitre Novatchev Punkte 234995

Diese Umwandlung :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://www.w3.org/1999/xhtml"
 xmlns="http://www.w3.org/1999/xhtml" exclude-result-prefixes="x">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@onclick"/>

 <xsl:template match="x:input">
  <xsl:element name="input" namespace="http://www.w3.org/1999/xhtml">
   <xsl:attribute name="name">
     <xsl:value-of select="concat('n',substring(@name,2))"/>
   </xsl:attribute>
   <xsl:attribute name="id">
     <xsl:value-of select="concat('i',substring(@id,2))"/>
   </xsl:attribute>
   <xsl:attribute name="someNew">newVal</xsl:attribute>
    <xsl:apply-templates select=
    "@*[not(name()='name' or name()='id')] | node()"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

wenn sie auf das angegebene XML-Dokument angewendet wird:

<html xmlns="http://www.w3.org/1999/xhtml">
    <head>
        <meta http-equiv="Content-type" content="text/html;  charset=utf-8" />
    </head>
    <body>
        <div class="iDev">
            <div class="q">           T 
                <input type="radio" name="o0" id="t0" onclick="getFeedback()"/>
            </div>
            <div class="q">           T 
                <input type="radio" name="o1" id="t1" onclick="getFeedback()" />
            </div>
        </div>
    </body>
</html>

ändert die name y id Attribut und fügt ein neues Attribut zu jedem input Element. Es "löscht" auch das onclick Attribut :

<html xmlns="http://www.w3.org/1999/xhtml">
   <head>
      <meta http-equiv="Content-type" content="text/html;  charset=utf-8"/>
   </head>
   <body>
      <div class="iDev">
         <div class="q">           T 
                <input name="n0" id="i0" someNew="newVal" type="radio"/>
         </div>
         <div class="q">           T 
                <input name="n1" id="i1" someNew="newVal" type="radio"/>
         </div>
      </div>
   </body>
</html>

Beantwortet el 1 de August, 2012 von Dimitre Novatchev (234995 Punkte )

Entfernen von Attributen aus der gesamten XML-Datei mit XSLT

Antwort

Empfohlene Fragen

Top-Tags

CodeJaeger.com

Powered by:

Entfernen von Attributen aus der gesamten XML-Datei mit XSLT

Antwort

Verwandte Fragen

Empfohlene Fragen

Top-Tags

CodeJaeger.com

Powered by: