Was ist ein schneller Weg, um Zeilen in Vim zu kommentieren/entkommentieren?

Question

Ich habe eine Ruby-Code-Datei in vi geöffnet, es gibt Zeilen auskommentiert mit # :

class Search < ActiveRecord::Migration
  def self.up
    # create_table :searches do |t|
    #   t.integer :user_id
    #   t.string :name
    #   t.string :all_of
    #   t.string :any_of
    #   t.string :none_of
    #   t.string :exact_phrase
    # 
    #   t.timestamps
    # end
  end

  def self.down
    # drop_table :searches
  end
end

Angenommen, ich möchte alle Zeilen in der ersten def ... end Abschnitt. Was ist ein effizienter Weg, das in Vim zu tun?

Im Allgemeinen suche ich nach einer einfachen und flüssigen Möglichkeit, Zeilen zu kommentieren und zu entkommentieren. Hier habe ich es mit Ruby-Code zu tun, aber es könnte auch JavaScript sein ( // ) oder Haml ( -# ).

Answer 1

Geben Sie an, welche Zeilen in vim kommentiert werden sollen:

Decken Sie die Zeilennummern auf:

:set number

dann

:5,17s/^/#/     this will comment out line 5-17

oder dies:

:%s/^/#/        will comment out all lines in file

Answer 2

Kommentare umschalten

Wenn Sie nur Folgendes brauchen Kommentare hin- und herschalten Ich würde lieber mit Kommentar.vim von tpope .

Einrichtung

Erreger:

cd ~/.vim/bundle
git clone git://github.com/tpope/vim-commentary.git

vim-plug:

Plug 'tpope/vim-commentary'

Vundle:

Plugin 'tpope/vim-commentary'

Weitere Anpassungen

Fügen Sie dies zu Ihrer .vimrc-Datei hinzu: noremap <leader>/ :Commentary<cr>

Sie können nun Kommentare durch Drücken von Leader + / , genau wie Sublime und Atom.

Answer 3

Ich mache es folgendermaßen:

1. Gehen Sie zum ersten Zeichen in der ersten Zeile, die Sie auskommentieren wollen.

2. Hit Ctrl + q in GVIM oder Ctrl + v in VIM, dann gehen Sie nach unten und wählen Sie das erste Zeichen in den Zeilen aus, die Sie auskommentieren wollen.

3. Dann drücken Sie c und fügen Sie das Kommentarzeichen hinzu.

Das Aufheben von Kommentaren funktioniert auf die gleiche Weise, nur dass Sie statt des Kommentarzeichens ein Leerzeichen eingeben.

Answer 4

Ich habe mir einen einfachen Zusatz zu meiner .vimrc-Datei ausgedacht, der ziemlich gut funktioniert und leicht erweitert werden kann. Sie fügen einfach einen neuen Dateityp zur comment_map und seinem Kommentarführer hinzu.

Ich habe eine Zuordnung zu den Modi "Normal" und "Visuell" hinzugefügt, aber Sie können die Zuordnung nach Belieben ändern. Ich ziehe es vor, nur eine "Toggle"-Funktion zu haben. Man erträgt es, mehrere Zuordnungen usw. zu haben.

let s:comment_map = { 
    \   "c": '\/\/',
    \   "cpp": '\/\/',
    \   "go": '\/\/',
    \   "java": '\/\/',
    \   "javascript": '\/\/',
    \   "lua": '--',
    \   "scala": '\/\/',
    \   "php": '\/\/',
    \   "python": '#',
    \   "ruby": '#',
    \   "rust": '\/\/',
    \   "sh": '#',
    \   "desktop": '#',
    \   "fstab": '#',
    \   "conf": '#',
    \   "profile": '#',
    \   "bashrc": '#',
    \   "bash_profile": '#',
    \   "mail": '>',
    \   "eml": '>',
    \   "bat": 'REM',
    \   "ahk": ';',
    \   "vim": '"',
    \   "tex": '%',
    \ }

function! ToggleComment()
    if has_key(s:comment_map, &filetype)
        let comment_leader = s:comment_map[&filetype]
        if getline('.') =~ "^\\s*" . comment_leader . " " 
            " Uncomment the line
            execute "silent s/^\\(\\s*\\)" . comment_leader . " /\\1/"
        else 
            if getline('.') =~ "^\\s*" . comment_leader
                " Uncomment the line
                execute "silent s/^\\(\\s*\\)" . comment_leader . "/\\1/"
            else
                " Comment the line
                execute "silent s/^\\(\\s*\\)/\\1" . comment_leader . " /"
            end
        end
    else
        echo "No comment leader found for filetype"
    end
endfunction

nnoremap <leader><Space> :call ToggleComment()<cr>
vnoremap <leader><Space> :call ToggleComment()<cr>

Note :

Ich benutze keine Callbacks oder Hooks in den Dateitypen/Laden, weil ich finde, dass sie den Start von Vim mehr verlangsamen als die .vimrc statische Funktion/Karte tut, aber das ist nur meine Vorliebe. Ich habe auch versucht, es einfach und performant zu halten. Wenn Sie Autocommands verwenden, müssen Sie sicher sein, sie in eine Autocommand-Gruppe zu setzen, sonst werden die Rückrufe mehrmals pro geladener Datei zum Dateityp hinzugefügt und verursachen eine Menge Leistungseinbußen.

Answer 5

Verwenden Sie Control-V, um Textrechtecke auszuwählen: Gehen Sie zum ersten # Zeichen, Typ Ctrl + V bewegen Sie sich einmal nach rechts und dann nach unten, bis zum Ende der Kommentare. Jetzt tippen Sie x : Sie löschen alle # Zeichen, gefolgt von einem Leerzeichen.