In Mathematica, wie man Ausdrücke wie a == +/- b in a^2 == b^2 vereinfacht?

Question

In Mathematica, wie kann ich Ausdrücke wie a == b || a == -b in a^2 = b^2 vereinfachen? Jede Funktion, die ich ausprobiert habe (einschließlich Reduce, Simplify und FullSimplify), tut es nicht.

Beachten Sie, dass ich möchte, dass dies für beliebige (polynomiale) Ausdrücke a und b funktioniert. Als weiteres Beispiel,

a == b || a == -b || a == i b || a == -i b

(für imaginäres i) und

a^2 == b^2 || a^2 == -b^2

sollten beide zu a^4 == b^4 vereinfacht werden.

Hinweis: die Lösung sollte auf logischer Ebene funktionieren, damit keine anderen nicht verwandten logischen Fälle beeinträchtigt werden. Zum Beispiel,

a == b || a == -b || c == d

sollte zu

a^2 == b^2 || c == d.

Answer 1

Könnte eine Menge von Möglichkeiten in ein Produkt umwandeln, das null entsprechen muss.

expr = a == b || a == -b || a == I*b || a == -I*b;
eqn = Apply[Times, Apply[Subtract, expr, 1]] == 0

Out[30]= (a - b)*(a - I*b)*(a + I*b)*(a + b) == 0

Jetzt vereinfachen Sie das.

Simplify[eqn]

Out[32]= a^4 == b^4

Daniel Lichtblau

Answer 2

Der boolesche Ausdruck kann wie folgt in algebraische Form umgewandelt werden:

In[18]:= (a == b || a == -b || a == I b || a == -I b) /. {Or -> Times,
    Equal -> Subtract} // Expand

Out[18]= a^4 - b^4

---

BEARBEITEN

Als Antwort darauf, dass beim Auslassen von Teilen in anderen Variablen die Transformation durchgeführt wird, kann man die Or-Transformationsfunktion schreiben und in Simplify verwenden:

In[41]:= Clear[OrCombine];
OrCombine[Verbatim[Or][e__Equal]] := Module[{g},
  g = GatherBy[{e}, Variables[Subtract @@ #] &];
  Apply[Or, 
   Function[
     h, ((Times @@ (h /. {Equal -> Subtract})) // Expand) == 0] /@ g]
  ]

In[43]:= OrCombine[(a == b || a == -b || a == I b || a == -I b || 
   c == d)]

Out[43]= a^4 - b^4 == 0 || c - d == 0

Alternativ:

In[40]:= Simplify[(a == b || a == -b || a == I b || a == -I b || 
   c == d), TransformationFunctions -> {Automatic, OrCombine}]

Out[40]= a^4 == b^4 || c == d