Was ist ein pre-revprop-change-Hook in SVN und wie kann ich ihn erstellen?

Question

Ich wollte einen Protokollkommentar im Repository-Browser bearbeiten und erhielt eine Fehlermeldung, dass für das Repository kein pre-revprop-change-Hook existiert. Was ist ein "pre-revprop-change"-Haken, abgesehen von seinem unheimlichen Namen, und wie kann ich ihn erstellen?

Answer 1

Für Windows finden Sie hier einen Link zu einer Beispiel-Batchdatei, die nur Änderungen an der Protokollmeldung zulässt (nicht an anderen Eigenschaften):

http://ayria.livejournal.com/33438.html

Kopieren Sie den nachstehenden Code in eine Textdatei und nennen Sie sie pre-revprop-change.bat und speichern Sie sie im Verzeichnis \hooks Unterverzeichnis für Ihr Repository.

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Answer 2

Im Grunde ist es ein Skript, das gestartet wird, bevor eine nicht versionierte Eigenschaft im Repository geändert wird, so dass Sie genauer verwalten können, was in Ihrem Repository passiert.

In der SVN-Distribution gibt es Vorlagen für verschiedene Hooks, die sich im Unterverzeichnis /hooks befinden (*.tmpl, die Sie je nach Betriebssystem bearbeiten und umbenennen müssen, um sie zu aktivieren).

Answer 3

Für Linux, um die Ausgabe eines Protokollkommentars zu ermöglichen,

• Suchen Sie die Datei pre-revprop-change.tmpl im hooks Verzeichnis Ihres Repositorys
• Kopieren Sie die Datei in dasselbe Verzeichnis und benennen Sie sie um in pre-revprop-change
• der Datei eine Ausführungserlaubnis geben (für den Serverbenutzer, z. B. www-data )

Bearbeitet: (Dank an lindes)

• Danach müssen Sie das Skript möglicherweise so bearbeiten, dass es einen Exit-Wert von 0 für die Art von Bearbeitungen, die Sie zulassen möchten.

Answer 4

Hier ist der Link zu der Stack Overflow-Frage mit vielen gemeinsamen Haken Gängige Typen von Subversion-Hooks einschließlich der ursprünglichen Quelle der pre-revprop-change Haken für Windows hier gecrosspostet.

Sie sollten sich dorthin wenden, da sie im Laufe der Zeit verbessert werden können.

Answer 5

Danke #patmortech

Und ich habe Ihren Code hinzugefügt, der besagt, dass "nur derselbe Benutzer seinen Code ändern kann".

:: Only allow editing of the same user.
for /f "tokens=*" %%a in ( 
'"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %revision% %repository%') do ( 
set orgAuthor=%%a
)
if /I not "%userName%" == "%orgAuthor%" goto ERROR_SAME_USER